cmake_minimum_required(VERSION 3.11)
project(manus_ros2)

if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

# find dependencies
find_package(ament_cmake REQUIRED)
find_package(ament_index_cpp REQUIRED)
find_package(rclcpp REQUIRED)
find_package(std_msgs REQUIRED)
find_package(geometry_msgs REQUIRED)
find_package(manus_ros2_msgs REQUIRED)

add_executable(manus_data_publisher 
  src/manus_data_publisher.cpp
  src/ClientPlatformSpecific.cpp
  src/ManusDataPublisher.cpp)

# Use the ManusSDK directory bundled inside this package.
target_include_directories(manus_data_publisher PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include>
  ${CMAKE_CURRENT_SOURCE_DIR}/ManusSDK/include
)

target_link_directories(manus_data_publisher PRIVATE
  ${CMAKE_CURRENT_SOURCE_DIR}/ManusSDK/lib
)

# Link the integrated SDK build to avoid external gRPC / Protobuf dependencies.
target_link_libraries(manus_data_publisher
  ManusSDK_Integrated
  ncurses
)

target_compile_features(manus_data_publisher PUBLIC c_std_99 cxx_std_17)

install(TARGETS manus_data_publisher
  DESTINATION lib/${PROJECT_NAME})

# In-package ManusSDK/lib for runtime installation.
set(LIBRARY_DIR ${CMAKE_CURRENT_SOURCE_DIR}/ManusSDK/lib)

# Use the same integrated-build .so.
set(LIBRARY_FILE ${LIBRARY_DIR}/libManusSDK_Integrated.so)

install(FILES ${LIBRARY_FILE} DESTINATION lib/${PROJECT_NAME})

# Install calibration files.
install(DIRECTORY calibration/
  DESTINATION share/${PROJECT_NAME}/calibration)

set_target_properties(manus_data_publisher PROPERTIES INSTALL_RPATH "$ORIGIN")

ament_target_dependencies(manus_data_publisher rclcpp std_msgs geometry_msgs manus_ros2_msgs ament_index_cpp)

ament_package()
